Роза ветров в gnuplot

Розы ветров (нарисованные с помощью gnuplot) для городов Ровно (Рівне), Сарны (Сарни) и Луцк (Луцьк) в зависимости от повторяемости направлений ветра и средней скорости ветра по направлениям.

Розы ветров (повторяемость направлений ветра)

Розы ветров (средняя скорость ветра по направлениям)

Графики построены по данным из СНиП 2.01.01-82. Строительная климатология и геофизика

UPD 06.01.2010:

Скрипт гнуплот:

set title "Роза ветров, г. Ровно\n(повторяемость направлений ветра, %)" font "CALIBRI.TTF,16"
set encoding default

set polar
set angles degrees

set size square
unset border
set xtics axis nomirror
set ytics axis nomirror
set grid polar 45
set xrange [-30:30]
set yrange [-30:30]

set key right bottom
#set style line 1 lt 2 lw 3
#set key box

# labels
set label "С" at graph 0.52, 0.95 font "CALIBRI.TTF,14"
set label "СВ" at graph 0.80, 0.85 font "CALIBRI.TTF,14"
set label "В" at graph 0.95, 0.52 font "CALIBRI.TTF,14"
set label "ЮВ" at graph 0.80, 0.15 font "CALIBRI.TTF,14"
set label "Ю" at graph 0.52, 0.05 font "CALIBRI.TTF,14"
set label "ЮЗ" at graph 0.17, 0.15 font "CALIBRI.TTF,14"
set label "З" at graph 0.05, 0.52 font "CALIBRI.TTF,14"
set label "СЗ" at graph 0.17, 0.85 font "CALIBRI.TTF,14"

set label "lokee, http://lokee.rv.ua" at graph 0, 0 font "CALIBRI.TTF,8"

set terminal png small size 800,800 font "CALIBRI.TTF,10"

# line styles
set style line 1 linetype 1 linewidth 2 linecolor rgb "blue"
set style line 2 linetype 1 linewidth 2 linecolor rgb "red"

# wind rose
#load "wr-rivne-labels-jan.plt"
set output "wr-rivne.png"
plot "wr-rivne.dat" using 2:3 with lines linestyle 1 title "Январь"

set output "wr-rivne.png"
replot "wr-rivne.dat" using 2:4 with lines linestyle 2 title "Июль"

# роза ветров (скорость ветра)
unset title
set title "Роза ветров, г. Ровно\n(средняя скорость ветра по направлениям, м/с)" font "CALIBRI.TTF,16"

unset xrange
unset yrange
set xrange [-10:10]
set yrange [-10:10]
set xtics 2
set ytics 2

set output "wsr-rivne.png"
plot "wr-rivne.dat" using 2:5 with lines linestyle 1 title "Январь"

set output "wsr-rivne.png"
replot "wr-rivne.dat" using 2:6 with lines linestyle 2 title "Июль"

wr-rivne.dat

#  - направл.. % - - скорость. м/с -
# напр. угол Январь Июль Январь Июль
В 0 8 5 4.5 2.8
СВ 45 5 7 3.9 3.3
С 90 7 10 4.9 4.0
СЗ 135 12 23 6.5 4.9
З 180 27 29 7.5 4.6
ЮЗ 225 14 11 6.1 3.7
Ю 270 14 7 5.1 3.4
ЮВ 315 13 8 5.4 3.2
В 360 8 5 4.5 2.8